vCard Format Extensions for JSContact

R. Stepanek; M. Loffredo

doi:10.17487/RFC9554

RFC 9554: vCard Format Extensions for JSContact

R. Stepanek,
M. Loffredo

Proposed Standard

Abstract

This document defines a set of new properties for vCard and extends the use of existing ones. Their primary purpose is to align the same set of features between the JSContact and vCard formats, but the new definitions also aim to be useful within just the vCard format. This document updates RFC 6350 ("vCard Format Specification").¶

Status of This Memo

This is an Internet Standards Track document.¶

This document is a product of the Internet Engineering Task Force (IETF). It represents the consensus of the IETF community. It has received public review and has been approved for publication by the Internet Engineering Steering Group (IESG). Further information on Internet Standards is available in Section 2 of RFC 7841.¶

Information about the current status of this document, any errata, and how to provide feedback on it may be obtained at https://www.rfc-editor.org/info/rfc9554.¶

Copyright Notice

This document is subject to BCP 78 and the IETF Trust's Legal Provisions Relating to IETF Documents (https://trustee.ietf.org/license-info) in effect on the date of publication of this document. Please review these documents carefully, as they describe your rights and restrictions with respect to this document. Code Components extracted from this document must include Revised BSD License text as described in Section 4.e of the Trust Legal Provisions and are provided without warranty as described in the Revised BSD License.¶

This document may contain material from IETF Documents or IETF Contributions published or made publicly available before November 10, 2008. The person(s) controlling the copyright in some of this material may not have granted the IETF Trust the right to allow modifications of such material outside the IETF Standards Process. Without obtaining an adequate license from the person(s) controlling the copyright in such materials, this document may not be modified outside the IETF Standards Process, and derivative works of it may not be created outside the IETF Standards Process, except to format it for publication as an RFC or to translate it into languages other than English.¶

1. Introduction

The JSContact [RFC9553] format aims to be an alternative to the vCard [RFC6350] format for representation of contact and address book data. As such, it introduces new semantics that are not covered in the current definition of vCard and its various extensions. Converting contact data between the two formats is defined in [RFC9555] with the goal of not losing any semantics during conversion. To achieve this, this document defines a new set of properties for vCard and extends existing definitions.¶

1.1. Notational Conventions

The key words "MUST", "MUST NOT", "REQUIRED", "SHALL", "SHALL NOT", "SHOULD", "SHOULD NOT", "RECOMMENDED", "NOT RECOMMENDED", "MAY", and "OPTIONAL" in this document are to be interpreted as described in BCP 14 [RFC2119] [RFC8174] when, and only when, they appear in all capitals, as shown here.¶

1.2. ABNF Notations

The ABNF definitions in this document use the notations of [RFC5234]. ABNF rules not defined in this document are defined in either [RFC5234] (such as the ABNF for CRLF, WSP, DQUOTE, VCHAR, ALPHA, and DIGIT) or [RFC6350].¶

2. Updated Properties

2.1. ADR

This specification modifies the definition of the ADR property. It extends its structured value with additional address components to better support the variety of international addresses. It separates the address parts, which currently are typically combined in street address component values, into distinct components.¶

Implementations SHOULD write a combined value of these components in the street address component for backwards compatibility, but they SHOULD ignore the street component during reads if the ADR property value contains any of the new components.¶

The following change is made to the first paragraph under "Special note", as originally specified in Section 6.3.1 of [RFC6350]. The remaining paragraphs of that section in the original specification still apply.¶

Special note: The structured type value consists of a sequence of address components. The component values MUST be specified in their corresponding position. The structured type value corresponds, in sequence, to the¶

post office box;¶
extended address (e.g., apartment or suite number);¶
street address;¶
locality (e.g., city);¶
region (e.g., state or province);¶
postal code;¶
country name (full name in the language specified in Section 5.1 of [RFC6350]);¶
room, suite number, or identifier;¶
apartment number, extension designation, or box number;¶
building floor or level;¶
street number;¶
street name;¶
building, tower, or condominium;¶
block name or number;¶
subdistrict;¶
district;¶
landmark or another publicly known prominent feature that can substitute the street name and number (e.g., "White House" and "Taj Mahal"); and¶
the cardinal direction or quadrant (e.g., "north").¶

The following change is made to the definition of "ADR-value" under "ABNF", as originally specified in Section 6.3.1 of [RFC6350].¶

ABNF¶

ADR-value = ; defined in RFC 6350, Section 6.3.1.:
            ADR-component-pobox ";"
            ADR-component-ext ";"
            ADR-component-street ";"
            ADR-component-locality ";"
            ADR-component-region ";"
            ADR-component-code ";"
            ADR-component-country ";"
            ; defined in this document:
            ADR-component-room ";"
            ADR-component-apartment ";"
            ADR-component-floor ";"
            ADR-component-streetnumber ";"
            ADR-component-streetname ";"
            ADR-component-building ";"
            ADR-component-block ";"
            ADR-component-subdistrict ";"
            ADR-component-district ";"
            ADR-component-landmark ";"
            ADR-component-direction

ADR-component-pobox    = list-component
ADR-component-ext      = list-component
ADR-component-street   = list-component
ADR-component-locality = list-component
ADR-component-region   = list-component
ADR-component-code     = list-component
ADR-component-country  = list-component
ADR-component-room     = list-component
ADR-component-apartment = list-component
ADR-component-floor    = list-component
ADR-component-streetnumber = list-component
ADR-component-streetname = list-component
ADR-component-building = list-component
ADR-component-block    = list-component
ADR-component-subdistrict = list-component
ADR-component-district = list-component
ADR-component-landmark = list-component
ADR-component-direction = list-component

¶

The following change is made under "Example", as originally specified in Section 6.3.1 of [RFC6350].¶

Example: In this example, the post office box and the extended address components are absent. The street number and name are both added as separate components and are combined in the street component for backwards compatibility.¶

ADR;GEO="geo:12.3457,78.910":
  ;;123 Main Street;Any Town;CA;91921-1234;U.S.A
  ;;;;123;Main Street;;;;;;

¶

2.2. N

This specification modifies the definition of the N property. It extends its structured value with additional name components to better support international names and generation markers. In doing so, this also facilitates formatting N property values using the Unicode Common Locale Data Repository (CLDR) Person Name [CLDRPersonName] formatting standard.¶

One new component is for secondary surnames, because in some cultures, such secondary surname kinds are used to indicate the paternal and maternal family names or generational names indicating father or grandfather. Another new component indicates a generation ("II", "XVI") or parental relation ("Jr.", "Sr.").¶

Currently, implementations typically place secondary surnames in the family name component and generational markers in the honorific suffixes component. For backwards compatibility, implementations SHOULD add such values to both the newly defined components and their backwards-compatible counterpart. Reading N property values, implementations SHOULD ignore any value in the backwards-compatible component if an equal value is set in the new component accordingly. For example, a "Jr." that occurs in both honorific suffixes and generation should only be handled as a generational marker.¶

The following change is made to the first paragraph under "Special note", as originally specified in Section 6.2.2 of [RFC6350]. The remaining paragraphs of that section in the original specification still apply.¶

Special note: The structured property value corresponds, in sequence, to the¶

family names (also known as surnames);¶
given names;¶
additional names;¶
honorific prefixes;¶
honorific suffixes;¶
secondary surname; and¶
generation.¶

The following change is made under "ABNF", as originally specified in Section 6.2.2 of [RFC6350].¶

ABNF¶

N-param = "VALUE=text" / sort-as-param / language-param
             / altid-param / any-param
N-value = list-component 6(";" list-component)

¶

The following change is made under "Examples", as originally specified in Section 6.2.2 of [RFC6350].¶

Examples¶

N:Public;John;Quinlan;Mr.;Esq.

N:Stevenson;John;Philip,Paul;Dr.;Jr.,M.D.,A.C.P.;;Jr.

¶

No change is required for the definition of the SORT-AS parameter, but the new components also apply for use with this parameter.¶

3. New Properties

3.1. CREATED

Property name:

CREATED¶

Purpose:

Defines the date and time when the vCard was created.¶

Value type:

A single timestamp value.¶

Cardinality:

*1¶

Property parameters:

VALUE¶

Description:

This is the timestamp when the vCard was created. Copying the vCard across systems does not count as a new creation nor a new revision. Instead, the timestamp value typically stays unchanged for the existence of the vCard.¶

Format definition:

created       = "CREATED" createdparam ":" timestamp

createdparam  = *(
                 ;
                 ; The following are OPTIONAL
                 ; but MUST NOT occur more than once.
                 ;
                 (";" "VALUE" "=" "timestamp") /
                 ;
                 ; The following are OPTIONAL
                 ; and MAY occur more than once.
                 ;
                 (";" any-param)
                 ;
                 )

¶

Example(s):

CREATED:20220705T093412Z
CREATED;VALUE=TIMESTAMP:20211022T140000-05

¶

3.2. GRAMGENDER

Property name:

GRAMGENDER¶

Purpose:

Defines which grammatical gender to use in salutations and other grammatical constructs.¶

Value type:

A single text value that is restricted to an enumerated list of allowed values.¶

Cardinality:

*¶

Property parameters:

LANGUAGE¶

Description:

This property defines the grammatical gender that the contact prefers to be addressed by or referred to as in written or spoken form. For example, the German language distinguishes by grammatical gender in salutations such as "Sehr geehrte" (feminine) and "Sehr geehrter" (masculine). Multiple occurrences of this property MUST be distinguished by the LANGUAGE parameter.¶

Format definition:

gramgender       = "GRAMGENDER" gramgender-param
                      ":" gramgender-value

gramgender-param =
                *(
                 ;
                 ; The following are OPTIONAL
                 ; but MUST NOT occur more than once.
                 ;
                 (";" language-param) /
                 ;
                 ; The following are OPTIONAL
                 ; and MAY occur more than once.
                 ;
                 (";" any-param)
                 ;
                 )

gramgender-value = "animate" /
                   "common" /
                   "feminine" /
                   "inanimate" /
                   "masculine" /
                   "neuter" /
                   iana-token /
                   x-name

¶

Example(s):

GRAMGENDER;LANGUAGE=de:feminine

¶